formatNumber

def formatNumber = { attrs ->
        if (!attrs.containsKey('number')) {
            throwTagError("Tag [formatNumber] is missing required attribute [number]")
        }
        def number = attrs.get('number')
        if (number == null) return null
        def formatName = attrs.get('formatName')
        def format = attrs.get('format')
        def type = attrs.get('type')
        def locale = resolveLocale(attrs.get('locale'))
        if (type == null) {
            if (!format && formatName) {
                format = messageHelper(formatName,null,null,locale)
                if (!format) {
                    throwTagError("Attribute [formatName] of Tag [formatNumber] specifies a format key [$formatName] that does not exist within a message bundle!")
                }
            }
            else if (!format) {
                format = messageHelper( "number.format", { messageHelper( "default.number.format", "0", null, locale) } ,null ,locale)
            }
        }
        DecimalFormatSymbols dcfs = locale ? new DecimalFormatSymbols( locale ) : new DecimalFormatSymbols()
        DecimalFormat decimalFormat
        if (!type) {
            decimalFormat = new DecimalFormat(format, dcfs)
        }
        else {
            if (type == 'currency') {
                decimalFormat = NumberFormat.getCurrencyInstance(locale)
            }
            else if (type == 'number') {
                decimalFormat = NumberFormat.getNumberInstance(locale)
            }
            else if (type == 'percent') {
                decimalFormat = NumberFormat.getPercentInstance(locale)
            }
            else {
                throwTagError("Attribute [type] of Tag [formatNumber] specifies an unknown type. Known types are currency, number and percent.")
            }
        }
        // ensure formatting accuracy
        decimalFormat.setParseBigDecimal(true)
        if (attrs.get('currencyCode') != null) {
            Currency currency = Currency.getInstance(attrs.get('currencyCode') as String)
            decimalFormat.setCurrency(currency)
        }
        if (attrs.get('currencySymbol') != null) {
            dcfs = decimalFormat.getDecimalFormatSymbols()
            dcfs.setCurrencySymbol(attrs.get('currencySymbol') as String)
            decimalFormat.setDecimalFormatSymbols(dcfs)
        }
        if (attrs.get('groupingUsed') != null) {
            if (attrs.get('groupingUsed') instanceof Boolean) {
                decimalFormat.setGroupingUsed(attrs.get('groupingUsed'))
            }
            else {
                // accept true, y, 1, yes
                decimalFormat.setGroupingUsed(attrs.get('groupingUsed').toString().toBoolean() || attrs.get('groupingUsed').toString()=='yes')
            }
        }
        if (attrs.get('maxIntegerDigits') != null) {
            decimalFormat.setMaximumIntegerDigits(attrs.get('maxIntegerDigits') as Integer)
        }
        if (attrs.get('minIntegerDigits') != null) {
            decimalFormat.setMinimumIntegerDigits(attrs.get('minIntegerDigits') as Integer)
        }
        if (attrs.get('maxFractionDigits') != null) {
            decimalFormat.setMaximumFractionDigits(attrs.get('maxFractionDigits') as Integer)
        }
        if (attrs.get('minFractionDigits') != null) {
            decimalFormat.setMinimumFractionDigits(attrs.get('minFractionDigits') as Integer)
        }
        if (attrs.get('roundingMode') != null) {
            def roundingMode=attrs.get('roundingMode')
            if (!(roundingMode instanceof RoundingMode)) {
                roundingMode = RoundingMode.valueOf(roundingMode)
            }
            decimalFormat.setRoundingMode(roundingMode)
        }
        if (!(number instanceof Number)) {
            number = decimalFormat.parse(number as String)
        }
        def formatted
        try {
            formatted = decimalFormat.format(number)
        }
        catch(ArithmeticException e) {
            // if roundingMode is UNNECESSARY and ArithemeticException raises, just return original number formatted with default number formatting
            formatted = NumberFormat.getNumberInstance(locale).format(number)
        }
        return formatted
    }
    def resolveLocale(localeAttr) {
        def locale = localeAttr
        if (locale != null && !(locale instanceof Locale)) {
            locale = StringUtils.parseLocaleString(locale as String)
        }
        if (locale == null) {
            locale = RCU.getLocale(request)
            if (locale == null) {
                locale = Locale.getDefault()
            }
        }
        return locale
    }